module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = "us-east-1"

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region = "us-east-2"
  alias  = "failover"

  default_tags {
    tags = module.default_tags.tags
  }
}

terraform {
  backend "s3" {
    bucket  = "shared-orcd-terraform-state"
    key     = "shared/prod/test-spa/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_route53_zone" "domain" {
  name         = var.domain_name
  private_zone = false
}

module "s3_bucket_us_east_1" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.10.3"

  env                 = var.environment
  bucket_name         = var.service_name
  application_family  = var.application_family
  s3_read_only_policy = false
  block_public_access = true

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  bucket_policy_overrides = [
    data.aws_iam_policy_document.cdn_s3_us_east_1_policy_document.json,
  ]

  bucket_cors_rule = [
    {
      allowed_headers = ["*"]
      allowed_methods = ["GET"]
      allowed_origins = ["*"]
      expose_headers  = []
      max_age_seconds = 3000
    },
  ]
}

data "aws_iam_policy_document" "cdn_s3_us_east_1_policy_document" {
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      module.s3_bucket_us_east_1.s3_bucket_arn_output,
      "${module.s3_bucket_us_east_1.s3_bucket_arn_output}/*",
    ]

    principals {
      type        = "AWS"
      identifiers = [module.spa_environment.origin_access_identity_primary_arn]
    }
  }
}

module "s3_bucket_us_east_2" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.10.3"

  env                   = var.environment
  bucket_name           = "${var.service_name}-us-east-2"
  application_family    = var.application_family
  s3_read_only_policy   = false
  block_public_access   = true
  custom_logging_bucket = "shared-orcd-us-east-2-s3-logs"

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  bucket_policy_overrides = [
    data.aws_iam_policy_document.cdn_s3_us_east_2_policy_document.json,
  ]

  bucket_cors_rule = [
    {
      allowed_headers = ["*"]
      allowed_methods = ["GET"]
      allowed_origins = ["*"]
      expose_headers  = []
      max_age_seconds = 3000
    },
  ]

  providers = {
    aws = aws.failover
  }
}

data "aws_iam_policy_document" "cdn_s3_us_east_2_policy_document" {
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      module.s3_bucket_us_east_2.s3_bucket_arn_output,
      "${module.s3_bucket_us_east_2.s3_bucket_arn_output}/*",
    ]

    principals {
      type        = "AWS"
      identifiers = [module.spa_environment.origin_access_identity_primary_arn]
    }
  }
}

# Add WAF for all Prod orcd cloudfront distributions
module "waf" {
  source            = "git@github.com:theorchard/terraform-aws-waf.git//?ref=1.5.0"
  environment       = var.environment
  service_name      = "${var.service_name}-cloudfront"
  aws_region        = var.aws_region
  acl_scope         = "CLOUDFRONT"
  count_waf_enabled = false
  block_waf_enabled = true
  excluded_rules = [
    "NoUserAgent_HEADER",
  ]
}

module "spa_environment" {
  source = "git@github.com:theorchard/terraform-spa.git?ref=1.3.3"
  providers = {
    aws.primary  = aws
    aws.failover = aws.failover
  }

  environment                         = var.environment
  service_name                        = var.service_name
  application_family                  = var.application_family
  brand                               = var.brand
  custom_response_headers_policy_name = "Managed-SecurityHeadersPolicy"
  enable_centralized_cf_logs          = true
  domain_name                         = var.domain_name
  custom_waf_name                     = module.waf.waf_blocking_name_output
  # Pick two buckets in different regions. In qa/prod these values do not typically need to be specified.
  custom_origin_primary_s3_bucket_name  = module.s3_bucket_us_east_1.s3_bucket_name_output
  custom_origin_failover_s3_bucket_name = module.s3_bucket_us_east_2.s3_bucket_name_output
}


resource "aws_route53_record" "cname" {
  zone_id = data.aws_route53_zone.domain.zone_id
  name    = var.service_name
  type    = "CNAME"
  ttl     = "300"
  records = ["${module.spa_environment.cloudfront_distribution_domain_name}"]
}