provider "aws" {
  region = var.region
}

terraform {
  backend "s3" {
    bucket  = "prod-songwhip-terraform-state"
    key     = "prod/songwhip-queue/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

module "songwhip_queue_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=5.0.0"

  environment        = var.environment
  platform           = "javascript"
  service_name       = var.service_name
  application_family = var.application_family
}

module "sqs_songwhip_queue" {
  source = "git@github.com:theorchard/terraform-sqs.git?ref=2.4.1"

  environment        = var.environment
  application_family = var.application_family
  queue_name         = var.sqs_songwhip_queue_name

  # call the lambda as soon as a message is recieved
  sqs_delay_seconds = 0

  sqs_max_message_size           = 262144
  sqs_fifo_queue                 = "false"
  sqs_visibility_timeout_seconds = 30

  sqs_deadletter_enabled      = "true"
  deadletter_max_message_size = 262144

  # 14 days
  deadletter_message_retention_seconds = 1209600
}

module "lambda_songwhip_queue" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=5.2.3"

  environment                        = var.environment
  application_family                 = var.application_family
  lambda_function_timeout            = 30
  use_container_image                = false
  lambda_description                 = "songwhip-queue lambda proxy"
  lambda_name                        = var.lambda_songwhip_queue_name
  lambda_function_package_path       = "lambda.zip"
  lambda_function_handler            = "index.handler"
  lambda_runtime                     = "nodejs22.x"
  datadog_advanced_enabled           = true
  vpc_enabled                        = false
  zappa_s3_policy_enabled            = false
  sqs_event_enabled                  = true
  event_source_mapping_resource_type = "sqs"
  event_source_mapping_queue_name    = module.sqs_songwhip_queue.queue_name
  event_source_mapping_batch_size    = 1

  lambda_function_reserved_concurrent_executions = 64
  lambda_function_memory_size                    = 512

  lambda_function_environment_variables = {
    ENVIRONMENT                  = var.environment
    SQS_MESSAGE_HANDLER_ENDPOINT = "https://queue.songwhip.com/sqs/webhook"
    SENTRY_DSN                   = module.songwhip_queue_sentry_project.sentry_key_dsn_public_output
  }
}

# Create IAM user for the application to access the SQS queues and the DynamoDB table.
resource "aws_iam_user" "songwhip_queue" {
  name = "${var.environment}-${var.service_name}"
  tags = {
    terraformed        = true
    application_family = var.application_family
    role               = "service-user"
  }
}

# Access to the SQS queue
resource "aws_iam_user_policy_attachment" "songwhip_queue_sqs_policy_attachment" {
  user       = aws_iam_user.songwhip_queue.name
  policy_arn = module.sqs_songwhip_queue.sqs_minimal_policy_arn_output
}

data "aws_iam_policy_document" "songwhip_queue_policy_document" {
  # Access to the SQS dead-letter queue
  statement {
    effect = "Allow"

    actions = [
      "sqs:GetQueueAttributes",
      "sqs:GetQueueUrl",
      "sqs:ListQueues",
      "sqs:DeleteMessage",
      "sqs:ReceiveMessage",
      "sqs:SendMessage",
      "sqs:SendMessageBatch",
      "sqs:PurgeQueue",
    ]

    resources = [
      module.sqs_songwhip_queue.deadletter_queue_arn
    ]
  }

  # Access to the DynamoDB table
  statement {
    effect = "Allow"

    actions = [
      "dynamodb:BatchWriteItem",
      "dynamodb:DeleteItem",
      "dynamodb:GetItem",
      "dynamodb:PutItem",
      "dynamodb:Query",
      "dynamodb:UpdateItem",
      "dynamodb:Scan",
    ]

    resources = [
      "arn:aws:dynamodb:us-east-1:${data.aws_caller_identity.current.account_id}:table/${var.dynamodb_table_songwhip_queue_name}"
    ]
  }
}

resource "aws_iam_policy" "songwhip_queue_policy" {
  name   = "${var.environment}-${var.service_name}-policy"
  policy = data.aws_iam_policy_document.songwhip_queue_policy_document.json
}

resource "aws_iam_user_policy_attachment" "songwhip_queue_policy_attachment" {
  user       = aws_iam_user.songwhip_queue.name
  policy_arn = aws_iam_policy.songwhip_queue_policy.arn
}