provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-songwhip-terraform-state"
    key     = "qa/acm/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_route53_zone" "songwhip" {
  name         = var.domain_name
  private_zone = false
}

resource "aws_acm_certificate" "tls_cert" {
  domain_name               = "*.${data.aws_route53_zone.songwhip.name}"
  subject_alternative_names = [data.aws_route53_zone.songwhip.name]
  validation_method         = "DNS"

  options {
    certificate_transparency_logging_preference = "ENABLED"
  }

  tags = {
    environment  = var.environment
    service_name = var.service_name
    terraformed  = "true"
  }

  lifecycle {
    create_before_destroy = true
  }
}

data "cloudflare_zone" "zone" {
  name = "songwhip.com"
}

resource "cloudflare_record" "dns_validation_record" {
  for_each = {
    for validation_object in aws_acm_certificate.tls_cert.domain_validation_options : validation_object.domain_name => {
      name   = validation_object.resource_record_name
      record = validation_object.resource_record_value
      type   = validation_object.resource_record_type
    } if validation_object.domain_name == data.aws_route53_zone.songwhip.name # Don't create validation record for wildcard record as it's identical to the domain record
  }

  zone_id         = data.cloudflare_zone.zone.id
  name            = each.value.name
  value           = each.value.record
  type            = each.value.type
}

resource "aws_acm_certificate_validation" "certificate_validation" {
  certificate_arn         = aws_acm_certificate.tls_cert.arn
  validation_record_fqdns = aws_acm_certificate.tls_cert.domain_validation_options[*].resource_record_name
}