provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-songwhip-terraform-state"
    key     = "qa/iam/roles/fansifter-role/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "role" {
  source = "git@github.com:theorchard/terraform-iam-policies.git//modules/roles?ref=1.18.2"

  role_name                      = var.role_name
  application_families_to_access = var.application_families_to_access
}

data "aws_caller_identity" "current" {}

data "aws_iam_policy_document" "sqs_dlq_redrive" {
  statement {
    effect = "Allow"

    actions = [
      "sqs:StartMessageMoveTask",
      "sqs:CancelMessageMoveTask",
      "sqs:DeleteMessage",
      "sqs:ReceiveMessage",
      "sqs:SendMessage",
    ]

    resources = [
      "arn:aws:sqs:*:${data.aws_caller_identity.current.account_id}:*"
    ]
  }
}

resource "aws_iam_policy" "sqs_dlq_redrive" {
  name   = "${var.role_name}-sqs-dlq-redrive"
  policy = data.aws_iam_policy_document.sqs_dlq_redrive.json
}

resource "aws_iam_role_policy_attachment" "sqs_dlq_redrive" {
  role       = module.role.iam_role_name
  policy_arn = aws_iam_policy.sqs_dlq_redrive.arn
}