module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "qa-supply-chain-terraform-state"
    key     = "qa/split-synchronizer/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git//?ref=3.1.0"

  environment = var.environment
}

data "aws_route53_zone" "route53_zone" {
  name = "qa-supply-chain.theorchard.io."
}

data "aws_acm_certificate" "qa_supply_chain_theorchard_io" {
  domain   = "*.qa-supply-chain.theorchard.io"
  statuses = ["ISSUED"]
}

module "elasticache" {
  # checkov:skip=CKV_AWS_30:ElastiCache encryption in transit requires client library update.
  # checkov:skip=CKV_AWS_31:ElastiCache encryption in transit requires client library update.
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=3.1.1"

  providers = {
    aws.dns = aws
  }

  environment                      = var.environment
  service_name                     = var.service_name
  cache_engine                     = "redis"
  cache_subnet_group_name          = "${var.environment}-elasticache-subnet-group"
  cache_node_type                  = "cache.t4g.micro"
  cache_node_count                 = 2
  cache_parameter_group_name       = "default.redis7"
  redis_engine_version             = "7.1"
  vpc_id                           = module.vpc_info.vpc_id
  route53_zone_id                  = data.aws_route53_zone.route53_zone.zone_id
  application_family               = var.application_family
  additional_cidr_blocks_enabled   = true
  cache_transit_encryption_enabled = false
  additional_cidr_blocks = [
    "192.168.32.0/24",
    "192.168.40.0/22",
  ]
}

module "split_synchronizer_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=5.6.1"

  providers = {
    aws.dns = aws
  }

  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.region
  commit_sha                               = "latest"
  container_port                           = "3010"
  task_type                                = "web_service"
  desired_task_count                       = 0 # Add datadog monitoring when task size is greater than 0
  task_cpu                                 = 256
  task_memory                              = 512
  maximum_capacity                         = 0
  minimum_capacity                         = 0
  route53_zone_id                          = data.aws_route53_zone.route53_zone.zone_id
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = module.vpc_info.vpc_id
  https_listener_certificate_id            = split("/", data.aws_acm_certificate.qa_supply_chain_theorchard_io.arn)[1]
  health_check_path                        = "/info/ping"
  web_service_health_check_command         = "curl -u $${SPLIT_SYNC_ADMIN_USERNAME}:$${SPLIT_SYNC_ADMIN_PASSWORD} http://localhost:3010 || exit 1"
  application_family                       = var.application_family

  iam_managed_policy_attachments = [
    "arn:aws:iam::aws:policy/CloudWatchFullAccess"
  ]

  fargate_service_subnets = module.vpc_info.default_private_subnet_ids

  load_balancer_subnets = module.vpc_info.default_private_subnet_ids

  environment_variables = [
    {
      SPLIT_SYNC_REDIS_HOST = module.elasticache.redis_primary_endpoint_address
    },
    {
      SPLIT_SYNC_REDIS_PORT = "6379"
    },
    {
      SPLIT_SYNC_ADVANCED_PARAMETERS = "-config /var/app/config.json"
    }
  ]

  secrets = [
    {
      SPLIT_SYNC_APIKEY = "${var.environment}/${var.service_name}/SPLIT_SYNC_APIKEY"
    },
    {
      SPLIT_SYNC_ADMIN_USERNAME = "${var.environment}/${var.service_name}/SPLIT_SYNC_ADMIN_USERNAME"
    },
    {
      SPLIT_SYNC_ADMIN_PASSWORD = "${var.environment}/${var.service_name}/SPLIT_SYNC_ADMIN_PASSWORD"
    }
  ]
}

module "split_synchronizer_secrets" {
  source   = "git@github.com:theorchard/terraform-secrets-manager.git//?ref=1.5.1"
  for_each = toset(var.secrets_manager_secret_names)

  environment                    = var.environment
  service_name                   = var.service_name
  secret_name                    = each.value
  application_family             = var.application_family
  secret_recovery_window_in_days = 30
}