provider "aws" {
  region = var.aws_region
}

terraform {
  backend "s3" {
    bucket  = "qa-supply-chain-terraform-state"
    key     = "qa/vector/audit/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vector_audit_s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.10.0"

  bucket_name         = var.service_name
  env                 = var.environment
  application_family  = var.application_family
  s3_read_only_policy = false

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  lifecycle_rules_options_current_version_transition = [
    {
      prefix        = ""
      enabled       = true
      days          = 0
      storage_class = "INTELLIGENT_TIERING"
    }
  ]

  lifecycle_rules_options_noncurrent_version_transition = [
    {
      prefix        = ""
      enabled       = true
      days          = 0
      storage_class = "INTELLIGENT_TIERING"
    }
  ]
}

data "aws_iam_policy_document" "vector_audit_s3_policy_document" {
  statement {
    effect = "Allow"
    actions = [
      "s3:GetBucketLocation",
      "s3:GetBucketVersioning",
      "s3:GetLifecycleConfiguration",
      "s3:GetObject",
      "s3:GetObjectAcl",
      "s3:GetObjectTorrent",
      "s3:GetObjectVersion",
      "s3:GetObjectVersionAcl",
      "s3:GetObjectVersionTorrent",
      "s3:GetReplicationConfiguration",
      "s3:ListBucket",
      "s3:ListBucketMultipartUploads",
      "s3:ListBucketVersions",
      "s3:ListMultipartUploadParts",
      "s3:PutObject",
      "s3:PutObjectAcl",
      "s3:PutObjectVersionAcl"
    ]

    resources = [
      "${module.vector_audit_s3_bucket.s3_bucket_arn_output}/*",
      "${module.vector_audit_s3_bucket.s3_bucket_arn_output}",
    ]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:ListAllMyBuckets",
      "s3:GetBucketLocation"
    ]

    resources = ["*"]
  }

  statement {
    effect = "Allow"
    actions = [
      "s3:GetBucketLocation",
      "s3:ListBucket"
    ]

    resources = ["${module.vector_audit_s3_bucket.s3_bucket_arn_output}"]
  }
}

resource "aws_iam_policy" "vector_audit_s3_policy" {
  name   = "S3-${module.vector_audit_s3_bucket.s3_bucket_name_output}-RW-policy"
  policy = data.aws_iam_policy_document.vector_audit_s3_policy_document.json
}