provider "aws" {
  region = var.aws_region
}

provider "aws" {
  alias  = "aws_us_west_2"
  region = "us-west-2"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "uat/frontend-documents/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_route53_zone" "domain" {
  name         = var.domain_name
  private_zone = true
}

module "frontend_documents_sentry_project" {
  source = "git@github.com:theorchard/terraform-sentry.git?ref=5.0.0"

  environment        = var.environment
  platform           = "javascript"
  service_name       = "frontend-${var.service_name_suffix}"
  application_family = var.application_family
}

module "spa_environment" {
  # checkov:skip=CKV_AWS_374:Ensure AWS CloudFront web distribution has geo restriction enabled.
  source = "git@github.com:theorchard/terraform-spa.git//?ref=1.4.1"
  providers = {
    aws.primary  = aws
    aws.failover = aws.aws_us_west_2
  }
  environment         = var.environment
  service_name        = var.service_name_suffix
  application_family  = var.application_family
  brand               = var.service_name
  domain_name         = var.domain_name
  default_root_object = "index.html"
  custom_s3_origin_path                 = "/frontend-documents"
  use_only_additional_aliases           = true
  custom_origin_failover_s3_bucket_name = "${var.environment}-orcd-cdn-us-west02"
  additional_aliases = [
    "${var.environment}-${var.service_name_suffix}.${var.domain_name}",
  ]
}

resource "aws_route53_record" "route53_record" {
  name    = "${var.environment}-${var.service_name_suffix}"
  zone_id = data.aws_route53_zone.domain.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [module.spa_environment.cloudfront_distribution_domain_name]
}