module "default_tags" {
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=2.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
  team_name          = var.team_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "uat/kafka-infra/kafka-cluster-artist-diy/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "vpc_info" {
  source = "git@github.com:theorchard/terraform-vpc-info.git?ref=3.1.0"

  environment = var.environment
}

# Amazon MSK cluster
module "artist_diy_managed_cluster" {
  source = "git@github.com:theorchard/terraform-managed-kafka.git?ref=3.1.1"

  environment                        = var.environment
  application_family                 = var.application_family
  additional_tags                    = var.additional_tags
  cluster_name                       = var.service_name
  kafka_version                      = "3.9.x"
  kafka_instance_type                = "kafka.m5.large"
  kafka_num_nodes                    = 3
  kafka_ebs_volume_size              = 500
  kafka_properties                   = "kafka_properties.conf"
  vpc_id                             = module.vpc_info.vpc_id
  datadog_enabled                    = true
  kafka_storage_scaling_target_value = 50
  subnet_ids                         = slice(module.vpc_info.default_private_subnet_ids, 0, 3) # because there are 3 nodes.
  kafka_allowed_custom_prefix_list_names = [
    "shared-orcd-atlantis-private-subnet-prefix-list", # Module default, allow access from Atlantis
    "uat-accounting-private-subnet-prefix-list",       # Allow services in Accounting UAT networks
  ]
}

module "datadog_dashboard" {
  source       = "git@github.com:theorchard/terraform-datadog.git//modules/msk?ref=6.18.2"
  environment  = var.environment
  cluster_name = var.service_name
}