module "default_tags" {
  # checkov:skip=ORCD_AWS_2: Avoid using old terraform module versions that are non Checkov compliant
  source             = "git@github.com:theorchard/terraform-default-tags.git//?ref=1.0.0"
  environment        = var.environment
  application_family = var.application_family
  service_name       = var.service_name
}

provider "aws" {
  region = var.aws_region

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region  = var.aws_region
  alias   = "networking"
  profile = "networking"

  default_tags {
    tags = module.default_tags.tags
  }
}

provider "aws" {
  region = "us-west-2"
  alias  = "failover"

  default_tags {
    tags = module.default_tags.tags
  }
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "uat/orcd-cdn/us-east-1/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_caller_identity" "current" {}

data "aws_cloudfront_response_headers_policy" "response_headers_policy" {
  name = "${var.environment}-default"
}

data "aws_route53_zone" "domain" {
  name         = var.domain_name
  private_zone = false
}

data "aws_route53_zone" "domain_networking" {
  provider = aws.networking

  name         = var.domain_name
  private_zone = false
}

data "aws_acm_certificate" "certificate" {
  domain   = "*.${data.aws_route53_zone.domain.name}"
  statuses = ["ISSUED"]
}

data "aws_wafv2_web_acl" "waf" {
  name  = "${var.environment}-orcd-cloudfront-waf-block"
  scope = "CLOUDFRONT"
}

data "aws_s3_bucket" "failover_bucket" {
  # This data source is used to reference the failover bucket in the origin group
  provider = aws.failover
  bucket   = "${var.environment}-${var.service_name}-us-west02"
}

module "s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.12.1"

  env                 = var.environment
  bucket_name         = var.service_name
  application_family  = var.application_family
  s3_read_only_policy = true
  block_public_access = true

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  bucket_policy_overrides = [
    data.aws_iam_policy_document.cdn_s3_policy_document.json,
  ]

  bucket_cors_rule = [
    {
      allowed_headers = ["*"]
      allowed_methods = ["GET"]
      allowed_origins = ["*"]
      expose_headers  = []
      max_age_seconds = 3000
    },
  ]

  apply_replication_configuration = [
    {
      prefix                            = ""
      enabled                           = true
      destination_bucket                = data.aws_s3_bucket.failover_bucket.id
      delete_marker_replication_enabled = true
      storage_class                     = "STANDARD"
    }
  ]
}

resource "aws_cloudfront_origin_access_identity" "cdn_origin_access_identity" {
  comment = "access-identity-${var.environment}-${var.service_name}.s3.amazonaws.com"
}

data "aws_iam_policy_document" "cdn_s3_policy_document" {
  # CDN Origin Access Identity
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      module.s3_bucket.s3_bucket_arn_output,
      "${module.s3_bucket.s3_bucket_arn_output}/*",
    ]

    principals {
      type        = "AWS"
      identifiers = [aws_cloudfront_origin_access_identity.cdn_origin_access_identity.iam_arn]
    }
  }

  # frontend-royalties
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-royalties/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_royalties_origin_access_identity_arns
    }
  }

  # frontend-documents
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-documents/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_documents_origin_access_identity_arns
    }
  }
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-documents/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_documents_awal_origin_access_identity_arns
    }
  }
}

resource "aws_cloudfront_distribution" "distribution" {
  # checkov:skip=CKV2_AWS_47:Rule requires the AWSManagedRulesAnonymousIpList to be enabled on the WAF, which blocks legitimate traffic.
  # checkov:skip=CKV_AWS_374:Ensure AWS CloudFront web distribution has geo restriction enabled. It's a CDN. We don't intend to restrict by geo-location for this use case.
  aliases = [
    "${var.environment}-cdn.${var.domain_name}",
  ]
  comment             = "${var.environment}-${var.service_name}"
  enabled             = true
  is_ipv6_enabled     = true
  http_version        = "http2"
  price_class         = "PriceClass_All"
  web_acl_id          = data.aws_wafv2_web_acl.waf.arn
  default_root_object = "robots.txt"

  origin_group {
    origin_id = var.s3_origin_group_name

    failover_criteria {
      status_codes = var.failover_criteria_status_codes
    }

    member {
      origin_id = "S3-${var.environment}-${var.service_name}"
    }

    member {
      origin_id = "S3-${var.environment}-${var.service_name}-us-west02" # This is the failover origin, typically in a different region
    }
  }

  origin {
    domain_name = module.s3_bucket.s3_bucket_domain_name_output
    origin_id   = "S3-${var.environment}-${var.service_name}"

    s3_origin_config {
      origin_access_identity = aws_cloudfront_origin_access_identity.cdn_origin_access_identity.cloudfront_access_identity_path
    }
  }

  origin {
    domain_name = data.aws_s3_bucket.failover_bucket.bucket_domain_name
    origin_id   = "S3-${var.environment}-${var.service_name}-us-west02"

    s3_origin_config {
      origin_access_identity = aws_cloudfront_origin_access_identity.cdn_origin_access_identity.cloudfront_access_identity_path
    }
  }

  default_cache_behavior {
    allowed_methods        = var.allowed_methods
    cached_methods         = var.cached_methods
    default_ttl            = var.default_ttl
    min_ttl                = 0
    max_ttl                = 31536000
    compress               = true
    target_origin_id       = var.s3_origin_group_name
    viewer_protocol_policy = "redirect-to-https"

    response_headers_policy_id = data.aws_cloudfront_response_headers_policy.response_headers_policy.id

    forwarded_values {
      query_string = false
      headers = [
        "Origin",
        "Access-Control-Request-Method",
        "Access-Control-Request-Headers",
      ]

      cookies {
        forward = "none"
      }
    }
  }

  restrictions {
    geo_restriction {
      restriction_type = "none"
    }
  }

  viewer_certificate {
    acm_certificate_arn      = data.aws_acm_certificate.certificate.arn
    ssl_support_method       = "sni-only"
    minimum_protocol_version = var.cloudfront_minimum_protocol_version
  }

  logging_config {
    include_cookies = true
    bucket          = var.cloudfront_logging_bucket
    prefix          = "AWSLogs/${data.aws_caller_identity.current.account_id}/CloudfrontLogs/${var.environment}-${var.service_name}/" # Ensure logs are stored in a path that includes the environment and service name
  }
}

resource "aws_route53_record" "route53_record" {
  name    = "${var.environment}-cdn"
  zone_id = data.aws_route53_zone.domain.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [aws_cloudfront_distribution.distribution.domain_name]
}

resource "aws_route53_record" "route53_record_networking" {
  provider = aws.networking

  name    = "${var.environment}-cdn"
  zone_id = data.aws_route53_zone.domain_networking.zone_id
  type    = "CNAME"
  ttl     = "60"
  records = [aws_cloudfront_distribution.distribution.domain_name]
}