provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "uat/orcd-cdn/us-west-2/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

data "aws_iam_role" "replication_role" {
  name = "S3-${var.environment}-orcd-cdn-replication-role"
}

module "s3_bucket" {
  source = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=3.12.1"

  env                   = var.environment
  bucket_name           = var.service_name
  application_family    = var.application_family
  s3_read_only_policy   = true
  block_public_access   = true
  custom_logging_bucket = "aws-logs-437795906767-us-west-2"

  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }

  bucket_policy_overrides = [
    data.aws_iam_policy_document.cdn_s3_policy_document.json,
  ]

  apply_replication_destination_configuration = [{
    replication_source_iam_role_arn = data.aws_iam_role.replication_role.arn
  }]
}

data "aws_cloudfront_origin_access_identity" "cdn_origin_access_identity" {
  id = "E38ZZ3GX1VR3NU" # access-identity-${var.environment}-orcd-cdn.s3.amazonaws.com
}

data "aws_iam_policy_document" "cdn_s3_policy_document" {
  # CDN Origin Access Identity
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      module.s3_bucket.s3_bucket_arn_output,
      "${module.s3_bucket.s3_bucket_arn_output}/*",
    ]

    principals {
      type        = "AWS"
      identifiers = [data.aws_cloudfront_origin_access_identity.cdn_origin_access_identity.iam_arn]
    }
  }

  # frontend-royalties
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-royalties/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_royalties_origin_access_identity_arns
    }
  }

  # frontend-documents
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-documents/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_documents_origin_access_identity_arns
    }
  }
  statement {
    actions = [
      "s3:GetObject",
    ]

    resources = [
      "${module.s3_bucket.s3_bucket_arn_output}/frontend-documents/*",
    ]

    principals {
      type        = "AWS"
      identifiers = var.frontend_documents_awal_origin_access_identity_arns
    }
  }
}