data "aws_caller_identity" "current" {}

data "aws_iam_policy_document" "elastictranscoder_execution_iam_policy" {
  statement {
    effect = "Allow"

    actions = [
      "s3:ListBucket",
    ]

    resources = [
      "arn:aws:s3:::${var.environment}-orcd-raw-assets",
      "arn:aws:s3:::${var.environment}-orcd-mezzanine-assets",
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "s3:Get*",
    ]

    resources = [
      "arn:aws:s3:::${var.environment}-orcd-raw-assets/*",
      "arn:aws:s3:::${var.environment}-orcd-mezzanine-assets/*",
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "s3:Put*",
      "s3:*MultipartUpload*",
    ]

    resources = [
      "arn:aws:s3:::${var.environment}-orcd-mezzanine-assets/*",
    ]
  }

  statement {
    effect = "Allow"

    actions = [
      "sns:Publish",
    ]

    resources = [
      "arn:aws:sns:us-east-1:${data.aws_caller_identity.current.account_id}:${var.environment}-asset_encoding_status",
    ]
  }

  statement {
    effect = "Deny"

    actions = [
      "s3:*Policy*",
      "s3:*Delete*",
      "sns:*Remove*",
    ]

    resources = [
      "arn:aws:s3:::${var.environment}-orcd-raw-assets",
      "arn:aws:s3:::${var.environment}-orcd-mezzanine-assets",
    ]
  }
}

data "aws_iam_policy_document" "assume_elastictranscoder_role" {
  statement {
    actions = ["sts:AssumeRole"]

    principals {
      type        = "Service"
      identifiers = ["elastictranscoder.amazonaws.com"]
    }
  }
}

resource "aws_iam_role" "elastictranscoder_role" {
  name               = "${var.environment}_assets_elastictranscoder_role"
  assume_role_policy = "${data.aws_iam_policy_document.assume_elastictranscoder_role.json}"
}

resource "aws_iam_policy" "elastictranscoder_policy" {
  name   = "elastictranscoder-${var.environment}-audio-assets"
  policy = "${data.aws_iam_policy_document.elastictranscoder_execution_iam_policy.json}"
}

resource "aws_iam_role_policy_attachment" "elastictranscoder_policy_attachment" {
  role       = "${aws_iam_role.elastictranscoder_role.name}"
  policy_arn = "${aws_iam_policy.elastictranscoder_policy.arn}"
}

resource "aws_elastictranscoder_pipeline" "assets_elastictranscoder" {
  input_bucket = "${var.raw_assets_bucket}"
  name         = "audio_assets_elastictranscoder"
  role         = "${aws_iam_role.elastictranscoder_role.arn}"

  content_config {
    bucket        = "${var.mezzanine_assets_bucket}"
    storage_class = "Standard"
  }

  thumbnail_config {
    bucket        = "${var.mezzanine_assets_bucket}"
    storage_class = "Standard"
  }

  notifications {
    error       = "arn:aws:sns:us-east-1:${data.aws_caller_identity.current.account_id}:${var.environment}-asset_encoding_status"
    completed   = "arn:aws:sns:us-east-1:${data.aws_caller_identity.current.account_id}:${var.environment}-asset_encoding_status"
    warning     = "arn:aws:sns:us-east-1:${data.aws_caller_identity.current.account_id}:${var.environment}-asset_encoding_status"
    progressing = "arn:aws:sns:us-east-1:${data.aws_caller_identity.current.account_id}:${var.environment}-asset_encoding_status"
  }
}