provider "aws" {
  region = "us-east-1"
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-analytics/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

resource "aws_elasticache_replication_group" "elasticache_instance" {
  replication_group_id          = "${var.environment}-${var.service_name}"
  replication_group_description = "${var.environment}-${var.service_name}"
  node_type                     = "cache.m3.medium"
  number_cache_clusters         = 2
  port                          = 6379
  availability_zones            = ["us-east-1b", "us-east-1c"]
  auto_minor_version_upgrade    = false
  automatic_failover_enabled    = true
  subnet_group_name             = "prod-vpc-orchard-subnet"
  snapshot_retention_limit      = 7
  apply_immediately             = "true"
}

module "ows_analytics_etl_environment_prod" {
  source = "git@github.com:theorchard/terraform-elasticbeanstalk.git"

  environment                        = var.environment
  service_name                       = "ows-analytics-etl"
  use_existing_application           = true
  existing_application_name          = "ows-analytics"
  launchconfiguration_instance_type  = "t3.medium"
  update_max_batch                   = "1"
  vpc_subnets                        = "subnet-067a6b45b079d7296,subnet-043d235081c966332"
  vpc_id                             = "vpc-7f0e841a"
  aws_route53_zone_id                = "Z2RSKZ9M7TJ9Z"
  elb_v2_access_logs_s3_bucket       = "aws-logs-437795906767-us-east-1"
  environment_tier                   = "Worker"
  notification_endpoints             = "data-squad@theorchard.com"
  vpc_elb_subnets                    = "subnet-5366ef24"
  process_instance_health_check_path = ""

  environment_variables = [
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "Environment"
      value     = var.environment
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "AWS_REGION"
      value     = var.aws_region
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "AWS_ACCESS_KEY_ID"
      value     = var.AWS_ACCESS_KEY_ID
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "AWS_SECRET_ACCESS_KEY"
      value     = var.AWS_SECRET_ACCESS_KEY
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "REDSHIFT_READ_ONLY_DB"
      value     = var.REDSHIFT_READ_ONLY_DB
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "REDSHIFT_READ_ONLY_HOST"
      value     = var.REDSHIFT_READ_ONLY_HOST
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "REDSHIFT_READ_ONLY_PORT"
      value     = var.REDSHIFT_READ_ONLY_PORT
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "REDSHIFT_READ_ONLY_USER"
      value     = var.REDSHIFT_READ_ONLY_USER
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "SENTRY_DSN"
      value     = var.SENTRY_DSN
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "SNOWFLAKE_ACCOUNT"
      value     = var.SNOWFLAKE_ACCOUNT
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "SNOWFLAKE_DATABASE"
      value     = var.SNOWFLAKE_DATABASE
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "SNOWFLAKE_PASSWORD"
      value     = var.SNOWFLAKE_PASSWORD
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "SNOWFLAKE_ROLE"
      value     = var.SNOWFLAKE_ROLE
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "SNOWFLAKE_SCHEMA"
      value     = var.SNOWFLAKE_SCHEMA
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "SNOWFLAKE_USER"
      value     = var.SNOWFLAKE_USER
    },
    {
      namespace = "aws:elasticbeanstalk:application:environment"
      name      = "SNOWFLAKE_WAREHOUSE"
      value     = var.SNOWFLAKE_WAREHOUSE
    },
  ]
}

module "analytics_metadata_dynamodb_table" {
  source = "git@github.com:theorchard/terraform-dynamodb.git//?ref=1.1.4"

  env               = var.environment
  table_name        = "analytics_metadata"
  range_key_enabled = true
  read_capacity     = "10"
  hash_key          = "first_id"
  hash_type         = "S"
  range_key         = "second_id"
  range_type        = "S"
}

module "ows_legacy_analytics_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.0.0"

  environment_name = var.environment
  service_name     = "ows-legacy-analytics"
}

module "ows_analytics_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.0.0"

  environment_name = var.environment
  service_name     = var.service_name
}

data "aws_iam_policy_document" "secrets_manager_policy" {
  statement { 
    effect  = "Allow"
    actions = [
      "secretsmanager:GetSecretValue"
    ]

    resources = [
        "arn:aws:secretsmanager:*:*:secret:prod/python-orchard-features/*",
        "arn:aws:secretsmanager:*:*:secret:prod/python-orchard-features/"
    ]
  }
}

resource "aws_iam_policy" "secrets_manager_policy" {
  name   = "${var.environment}-ows-analytics-secrets-manager-policy"
  policy = data.aws_iam_policy_document.secrets_manager_policy.json
}

# Old ows-analytics, now known as ows-legacy-analytics
module "ows_legacy_analytics_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=1.5.3"

  environment                              = var.environment
  service_name                             = "ows-legacy-analytics"
  aws_region                               = var.aws_region
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 1024
  task_memory                              = 2048
  maximum_capacity                         = 4
  minimum_capacity                         = 2
  scale_up_adjustment                      = 1
  scale_down_adjustment                    = -1
  route53_zone_id                          = "Z2RSKZ9M7TJ9Z"
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = "vpc-7f0e841a"
  datadog_function_destination_arn         = "arn:aws:lambda:us-east-1:437795906767:function:DatadogLambdaFunction"
  https_listener_certificate_id            = "a76e4883-28aa-4062-a4cc-c06b8012ae28"
  http_listener_enabled                    = false
  health_check_grace_period_seconds        = 300

  iam_managed_policy_attachments = [
    "arn:aws:iam::437795906767:policy/Dynamo-prod-ows-analytics-owsrequest",
    "arn:aws:iam::437795906767:policy/Dynamo-prod-ows-legacy-analytics-owsrequest",
    "arn:aws:iam::437795906767:policy/Dynamo-prod-streams_vendor_totals-RW",
    "arn:aws:iam::437795906767:policy/Dynamo-prod-stream-wildcard-RW",
    "arn:aws:iam::437795906767:policy/Dynamo-stream-wildcard-RW",
    "arn:aws:iam::437795906767:policy/prod-aggregate-analytics",
  ]

  fargate_service_subnets = [
    "subnet-067a6b45b079d7296",
    "subnet-043d235081c966332",
  ]

  load_balancer_subnets = [
    "subnet-067a6b45b079d7296",
    "subnet-043d235081c966332",
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    },
    {
      DATADOG_ENV = "${var.environment}-ows-legacy-analytics"
    },
    {
      DD_LOGS_INJECTION = "true"
    }
  ]
}

# New ows-analytics (FKA bff-mobile)
module "ows_analytics_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=1.7.11"

  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.aws_region
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 5
  task_cpu                                 = 4096
  task_memory                              = 8192
  maximum_capacity                         = 8
  minimum_capacity                         = 5
  route53_zone_id                          = "Z2RSKZ9M7TJ9Z"
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = "vpc-7f0e841a"
  https_listener_certificate_id            = "a76e4883-28aa-4062-a4cc-c06b8012ae28"
  http_listener_enabled                    = false
  health_check_grace_period_seconds        = 300

  prod_https_listener_allow_cidr_blocks = [
    "192.168.31.0/24",
    "192.168.40.0/22",
    "10.40.0.0/22",
    "10.30.0.0/22",
    "10.10.40.0/22",
    "10.120.0.0/24",
    "10.120.1.0/24",
  ]

  iam_managed_policy_attachments = [
    # May use bff-mobile or ows-analytics
    "arn:aws:iam::437795906767:policy/Dynamo-prod-mobile_metadata-RW",
    "arn:aws:iam::437795906767:policy/Dynamo-prod_analytics_metadata-RO",
    "arn:aws:iam::437795906767:policy/Dynamo-prod-bff-mobile-owsrequest",
    "arn:aws:iam::437795906767:policy/Dynamo-prod-ows-analytics-owsrequest",
    "arn:aws:iam::437795906767:policy/SecretsManager-prod-bff-mobile-policy",
    "arn:aws:iam::437795906767:policy/SecretsManager-prod-ows-analytics-policy",
    aws_iam_policy.secrets_manager_policy.arn
  ]

  fargate_service_subnets = [
    "subnet-067a6b45b079d7296",
    "subnet-043d235081c966332",
  ]

  load_balancer_subnets = [
    "subnet-067a6b45b079d7296",
    "subnet-043d235081c966332",
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      ANALYTICS_METADATA_TABLE = "prod_analytics_metadata"
    },
    {
      AWS_DEFAULT_REGION = "us-east-1"
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      DYNAMO_TABLE = "prod-mobile_metadata"
    },
    {
      LOGGER_DSN = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    }
  ]
}

module "elasticache" {
  source = "git@github.com:theorchard/terraform-elasticache.git//?ref=1.0.6"

  environment = var.environment
  # An ows-analytics elasticache cluster already exists, so append -cluster
  service_name            = "ows-analytics-cluster"
  cache_engine            = "redis"
  cache_subnet_group_name = "prod-private-vpc-subnet"
}

module "fargate_ows_legacy_analytics_service_dashboard" {
  source           = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=2.0.0"
  environment      = var.environment
  environment_type = "fargate"
  service_name     = "ows-legacy-analytics"
}

module "fargate_service_dashboard" {
  source           = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=2.0.0"
  environment      = var.environment
  environment_type = "fargate"
  service_name     = var.service_name
}

# Elasticsearch instance
module "elasticsearch_ows_analytics" {
  source = "git@github.com:theorchard/terraform-elasticsearch.git//?ref=1.2.0"

  env                        = var.environment
  aws_es_domain_name         = var.service_name
  aws_es_version             = 7.4
  dedicated_master_type      = "c5.large.elasticsearch"
  dedicated_master_count     = 3
  dedicated_master_enabled   = true
  aws_es_instance_type       = "r5.2xlarge.elasticsearch"
  aws_es_instance_count      = 3
  aws_es_disk_size           = 60
  vpc_subnet_ids             = ["subnet-5366ef24"]
  backup_s3_bucket_name      = "prod-orcdbucket"
  schedule_exp               = "cron(0 22 * * ? *)"
  vpc_security_group_ids     = ["sg-21f1ed44"]
  aws_route53_params_zone_id = "Z2RSKZ9M7TJ9Z"
  zone_awareness_enabled     = false
}

# Create IAM user for elasticsearch cache warm jenkins job."
resource "aws_iam_user" "cache_prewarm_user" {
  name = "prod-${var.service_name}-cache-prewarm-user"
  tags = {
    terraformed = true
  }
}

# Attach iam policies to cache-prewarm iam user.
resource "aws_iam_user_policy_attachment" "iam-user-policy-attachment" {
  user       = aws_iam_user.cache_prewarm_user.name
  count      = length(var.iam_policy_arn)
  policy_arn = var.iam_policy_arn[count.index]
}