provider "aws" {
  region = "us-east-1"
}

# Terraform backends cannot contain interpolations.
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "prod/ows-collaborator/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

# Set up rds master password.
data "aws_secretsmanager_secret" "rds_master_username" {
  name = "${var.environment}/${var.service_name}/rds_master_username"
}

data "aws_secretsmanager_secret_version" "rds_master_username" {
  secret_id = data.aws_secretsmanager_secret.rds_master_username.id
}

data "aws_secretsmanager_secret" "rds_master_password" {
  name = "${var.environment}/${var.service_name}/rds_master_password"
}

data "aws_secretsmanager_secret_version" "rds_master_password" {
  secret_id = data.aws_secretsmanager_secret.rds_master_password.id
}

data "aws_secretsmanager_secret" "sentry_dsn" {
  name = "${var.environment}/${var.service_name}/SENTRY_DSN"
}

data "aws_secretsmanager_secret_version" "sentry_dsn" {
  secret_id = data.aws_secretsmanager_secret.sentry_dsn.id
}

module "ows_service_owsrequest" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.0.0"

  environment_name = var.environment
  service_name     = var.service_name
}

module "ows_collaborator" {
  source = "git@github.com:theorchard/terraform-rds.git//?ref=1.0.0"

  environment                      = var.environment
  service_name                     = "ows-collaborator"
  rds_cluster_instance_count       = "1"
  rds_db_subnet_group_name         = "prod-orchard-private-subnet-group"
  rds_vpc_security_group_ids       = ["sg-21f1ed44"]
  rds_availability_zones           = ["us-east-1a", "us-east-1d"]
  rds_performance_insights_enabled = false
  rds_master_username              = data.aws_secretsmanager_secret_version.rds_master_username.secret_string
  rds_master_password              = data.aws_secretsmanager_secret_version.rds_master_password.secret_string
}

# Setup fargate environment.
module "ows_collaborator_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=1.1.6"

  environment                              = var.environment
  service_name                             = var.service_name
  aws_region                               = var.aws_region
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 512
  task_memory                              = 1024
  maximum_capacity                         = 4
  minimum_capacity                         = 1
  scale_up_adjustment                      = 1
  scale_down_adjustment                    = -1
  health_check_path                        = "/hello/"
  route53_zone_id                          = "Z2RSKZ9M7TJ9Z"
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = "vpc-7f0e841a"
  datadog_function_destination_arn         = "arn:aws:lambda:us-east-1:437795906767:function:DatadogLambdaFunction"
  https_listener_certificate_id            = "a76e4883-28aa-4062-a4cc-c06b8012ae28"
  iam_managed_policy_attachments = [
    module.ows_service_owsrequest.policy_arn_output,
    aws_iam_policy.swf_execution_policy.arn,
    aws_iam_policy.elasticsearch_read_write_access_policy.arn,
  ]

  fargate_service_subnets = [
    "subnet-067a6b45b079d7296",
    "subnet-043d235081c966332",
  ]

  load_balancer_subnets = [
    "subnet-067a6b45b079d7296",
    "subnet-043d235081c966332",
  ]

  environment_variables = [
    {
      Environment = var.environment
    },
    {
      DATADOG_ENV = "${var.environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      LOGGER_DSN = "https://prod-fluentd-applications.theorchard.io:8888/application"
    },
    {
      SENTRY_DSN = data.aws_secretsmanager_secret_version.sentry_dsn.secret_string
    },
  ]
}

# Setup datadog dashboards.
module "fargate_service_dashboard" {
  source           = "git@github.com:theorchard/terraform-datadog.git//modules/service?ref=1.0.0"
  environment      = var.environment
  environment_type = "fargate"
  service_name     = var.service_name
}

# Create Dynamo table
module "dynamo_ows_collaborator_reports" {
  source                         = "git@github.com:theorchard/terraform-dynamodb.git//?ref=1.0.0"
  env                            = var.environment
  table_name                     = "${var.service_name}-reports"
  hash_key                       = "user_id_type"
  hash_type                      = "S"
  range_key_enabled              = true
  range_key                      = "collaborator_params"
  range_type                     = "S"
  server_side_encryption_enabled = true
  max_read_capacity              = 100
  min_read_capacity              = 10
  read_capacity                  = 10
  max_write_capacity             = 20
  min_write_capacity             = 5
  write_capacity                 = 5
}

module "s3_ows_collaborator_reports" {
  source      = "git@github.com:theorchard/terraform-s3.git//modules/s3_bucket?ref=1.1.1"
  env         = var.environment
  bucket_name = "${var.service_name}-reports"
  apply_server_side_encryption_by_default = {
    sse_algorithm = "AES256"
  }
}

# Audit logging
module "elasticsearch_collaborator_audit_log" {
  source = "git@github.com:theorchard/terraform-elasticsearch.git//"

  env                        = var.environment
  aws_es_domain_name         = "${var.service_name}-log"
  aws_es_instance_type       = "m4.large.elasticsearch"
  aws_es_instance_count      = 1
  aws_es_disk_size           = 40
  vpc_subnet_ids             = ["subnet-067a6b45b079d7296"]
  backup_s3_bucket_name      = "prod-orcdbucket"
  schedule_exp               = "cron(0 22 * * ? *)"
  vpc_security_group_ids     = ["sg-21f1ed44"]
  aws_route53_params_zone_id = "Z2RSKZ9M7TJ9Z"
  zone_awareness_enabled     = false
}