data "aws_iam_policy_document" "assume_role_policy" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    principals {
      type = "AWS"

      identifiers = concat(var.additional_roles, [var.fargate_task_role])
    }
  }
}

resource "aws_iam_role" "ows_podcast_browser_upload_role" {
  name                 = "${var.environment}-ows-podcast-browser-upload-role"
  max_session_duration = 3600
  assume_role_policy   = data.aws_iam_policy_document.assume_role_policy.json
}

data "aws_iam_policy_document" "input_bucket_putonly_policy" {
  statement {
    effect = "Allow"

    actions = [
      "s3:PutObject",
      "s3:PutObjectAcl",
      "s3:PutObjectTagging",
      "s3:PutObjectVersionAcl",
      "s3:PutObjectVersionTagging",
    ]

    resources = [
      "${aws_s3_bucket.input_assets_bucket.arn}/*",
      "${aws_s3_bucket.output_bucket.arn}/copies/*",
    ]
  }
}

resource "aws_iam_policy" "input_bucket_putonly_policy" {
  name   = "S3-${aws_s3_bucket.input_assets_bucket.id}-WO"
  policy = data.aws_iam_policy_document.input_bucket_putonly_policy.json
}

resource "aws_iam_role_policy_attachment" "ows_podcast_browser_upload_policy_attachment" {
  role       = aws_iam_role.ows_podcast_browser_upload_role.id
  policy_arn = aws_iam_policy.input_bucket_putonly_policy.arn
}

data "aws_iam_policy_document" "ows_podcast_browser_upload_assume_role_policy_document" {
  statement {
    effect = "Allow"

    actions = [
      "sts:AssumeRole",
    ]

    resources = [
      aws_iam_role.ows_podcast_browser_upload_role.arn
    ]
  }
}

resource "aws_iam_policy" "ows_podcast_browser_upload_assume_role_policy" {
  name   = "${var.environment}-ows-podcast-browser-upload-assume-role-policy"
  policy = data.aws_iam_policy_document.ows_podcast_browser_upload_assume_role_policy_document.json
}