provider "aws" {
  region = var.aws_region
}

# Terraform backends cannot contain interpolations
terraform {
  backend "s3" {
    bucket  = "orcd-terraform-state"
    key     = "qa/ows-royalties/terraform.tfstate"
    region  = "us-east-1"
    encrypt = "true"
  }
}

module "ows_royalties_owsrequest" {
  source             = "git@github.com:theorchard/terraform-owsrequest.git//"
  policy_description = "A policy to access dynamo owsrequest table"

  environment_name = var.Environment
  service_name     = var.service_name
}

data "aws_secretsmanager_secret" "sentry_dsn" {
  name = "${var.Environment}/${var.service_name}/SENTRY_DSN"
}

data "aws_secretsmanager_secret_version" "sentry_dsn" {
  secret_id = data.aws_secretsmanager_secret.sentry_dsn.id
}

data "aws_secretsmanager_secret" "rds_master_username" {
  name = "${var.Environment}/${var.service_name}/rds_master_username"
}

data "aws_secretsmanager_secret_version" "rds_master_username" {
  secret_id = data.aws_secretsmanager_secret.rds_master_username.id
}

data "aws_secretsmanager_secret" "rds_master_password" {
  name = "${var.Environment}/${var.service_name}/rds_master_password"
}

data "aws_secretsmanager_secret_version" "rds_master_password" {
  secret_id = data.aws_secretsmanager_secret.rds_master_password.id
}

module "rds" {
  source = "git@github.com:theorchard/terraform-rds//"

  environment                               = var.Environment
  rds_engine                                = "aurora-postgresql"
  rds_engine_version                        = "9.6.12"
  service_name                              = var.service_name
  rds_db_subnet_group_name                  = "prod-orchard-private-subnet-group"
  rds_cluster_instance_parameter_group_name = "default.aurora-postgresql9.6"
  rds_db_cluster_parameter_group_name       = "default.aurora-postgresql9.6"
  rds_cluster_instance_class                = "db.r4.large"
  rds_vpc_security_group_ids                = ["sg-21f1ed44"]
  rds_cluster_instance_count                = "1"
  rds_master_username                       = data.aws_secretsmanager_secret_version.rds_master_username.secret_string
  rds_master_password                       = data.aws_secretsmanager_secret_version.rds_master_password.secret_string
  rds_availability_zones                    = ["us-east-1a", "us-east-1c"]
}

module "ows_royalties_fargate_environment" {
  source = "git@github.com:theorchard/terraform-fargate.git//?ref=1.1.1"

  environment                              = var.Environment
  service_name                             = var.service_name
  aws_region                               = var.aws_region
  commit_sha                               = "latest"
  container_port                           = "8080"
  task_type                                = "web_service"
  desired_task_count                       = 2
  task_cpu                                 = 512
  task_memory                              = 1024
  maximum_capacity                         = 4
  minimum_capacity                         = 1
  scale_up_adjustment                      = 1
  scale_down_adjustment                    = -1
  route53_zone_id                          = "Z2RSKZ9M7TJ9Z"
  load_balancer_access_logs_s3_bucket_name = "orch-elb-logs"
  vpc_id                                   = "vpc-7f0e841a"
  datadog_function_destination_arn         = "arn:aws:lambda:us-east-1:437795906767:function:DatadogLambdaFunction"
  https_listener_certificate_id            = "a76e4883-28aa-4062-a4cc-c06b8012ae28"
  iam_policy_file_enabled                  = true

  iam_managed_policy_attachments = [
    module.ows_royalties_owsrequest.policy_arn_output,
    "arn:aws:iam::437795906767:policy/Elasticsearch-qa-ows-royalties-log-RW",
  ]

  fargate_service_subnets = [
    "subnet-067a6b45b079d7296",
    "subnet-043d235081c966332",
  ]

  load_balancer_subnets = [
    "subnet-067a6b45b079d7296",
    "subnet-043d235081c966332",
  ]

  environment_variables = [
    {
      Environment = var.Environment
    },
    {
      LOGGER_DSN = "https://qa-fluentd-applications.theorchard.io:8888/application"
    },
    {
      DATADOG_ENV = "${var.Environment}-${var.service_name}"
    },
    {
      DD_LOGS_INJECTION = "true"
    },
    {
      SENTRY_DSN = data.aws_secretsmanager_secret_version.sentry_dsn.secret_string
    },
    {
      PG_DB_HOST = module.rds.rds_cluster_endpoint
    },
    {
      PG_DB_NAME = "ows_royalties"
    },
    {
      AUDIT_LOG_ES_ENDPOINT = module.elasticsearch_royalties_audit_log.aws_elasticsearch_endpoint_output
    },
  ]
}

module "fargate_service_dashboard" {
  source           = "git@github.com:theorchard/terraform-datadog.git//modules/service"
  environment      = var.Environment
  environment_type = "fargate"
  service_name     = var.service_name
}

# Accounting run Elasticsearch instance
module "elasticsearch_royalties_audit_log" {
  source = "git@github.com:theorchard/terraform-elasticsearch.git//"

  env                            = var.Environment
  aws_es_domain_name             = "${var.service_name}-log"
  aws_es_instance_type           = "t2.small.elasticsearch"
  aws_es_instance_count          = 1
  aws_es_disk_size               = 20
  vpc_subnet_ids                 = ["subnet-067a6b45b079d7296"]
  backup_s3_bucket_name          = "qa-orcdbucket"
  schedule_exp                   = "cron(0 22 * * ? *)"
  vpc_security_group_ids         = ["sg-21f1ed44"]
  aws_route53_params_zone_id     = "Z2RSKZ9M7TJ9Z"
  aws_es_version                 = "6.5"
  node_to_node_encryption_option = false
  encrypt_at_rest_enabled        = false
}