# Allow service to assume role for cross-account Kafka access
data "aws_iam_policy_document" "consumer_assume_role_policy" {
  statement {
    actions = [
      "sts:AssumeRole",
    ]

    resources = ["arn:aws:iam::662302927201:role/qa-orchard-access"]
  }
}

resource "aws_iam_policy" "consumer_assume_role_policy" {
  name   = "${var.environment}-${var.service_name}-sts-assume-role-policy"
  policy = data.aws_iam_policy_document.consumer_assume_role_policy.json
}

data "aws_secretsmanager_secret" "producer_sentry_dsn" {
  name = "${var.environment}/switchboard-producer/SENTRY_DSN"
}

data "aws_secretsmanager_secret_version" "producer_sentry_dsn" {
  secret_id = data.aws_secretsmanager_secret.producer_sentry_dsn.id
}

# Allow service to read shared graphql-switchboard secret
data "aws_iam_policy_document" "consumer_secrets_manager_policy" {
  statement {
    actions = [
      "secretsmanager:GetResourcePolicy",
      "secretsmanager:GetSecretValue",
      "secretsmanager:DescribeSecret",
      "secretsmanager:ListSecretVersionIds",
    ]

    resources = [
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/graphql-switchboard/CONSUMER_SECRET",
      "arn:aws:secretsmanager:*:*:secret:${var.environment}/graphql-switchboard/CONSUMER_SECRET*",
    ]
  }

  statement {
    actions = [
      "secretsmanager:GetRandomPassword",
    ]

    resources = [
      "*",
    ]
  }
}

resource "aws_iam_policy" "consumer_secrets_manager_policy" {
  name   = "${var.environment}-${var.service_name}-shared-secrets-manager-policy"
  policy = data.aws_iam_policy_document.consumer_secrets_manager_policy.json
}

data "aws_secretsmanager_secret" "graphql_consumer_secret" {
  name = "${var.environment}/graphql-switchboard/CONSUMER_SECRET"
}

resource "aws_iam_policy" "kinesis_readonly_policy" {
  name   = "${var.environment}-${var.service_name}-kinesis-RO-policy"
  policy = data.aws_iam_policy_document.kinesis_readonly_policy.json
}

data "aws_iam_policy_document" "kinesis_readonly_policy" {
  statement {
    actions = [
      "kinesis:ListShards",
      "kinesis:ListStreams",
      "kinesis:GetShardIterator",
      "kinesis:GetRecords",
      "kinesis:DescribeStream",
      "kinesis:DescribeStreamConsumer",
      "kinesis:DescribeStreamSummary",
    ]

    # TF-UPGRADE-TODO: In Terraform v0.10 and earlier, it was sometimes necessary to
    # force an interpolation expression to be interpreted as a list by wrapping it
    # in an extra set of list brackets. That form was supported for compatibility in
    # v0.11, but is no longer supported in Terraform v0.12.
    #
    # If the expression in the following list itself returns a list, remove the
    # brackets to avoid interpretation as a list of lists. If the expression
    # returns a single list item then leave it as-is and remove this TODO comment.
    resources = [
      module.switchboard_kinesis_stream.kinesis_stream_arn,
    ]
  }
}

module "switchboard_producer_owsrequest_policy" {
  source = "git@github.com:theorchard/terraform-owsrequest.git//?ref=1.0.0"

  environment_name = var.environment
  service_name     = "switchboard-producer"
}

resource "aws_security_group" "lambda_producer_security_group" {
  name        = "switchboard-producer-${var.environment}-security-group"
  description = "Security group for switchboard-producer-${var.environment} in ${var.vpc_id}"
  vpc_id      = var.vpc_id

  tags = {
    environment = var.environment
    terraformed = true
    name        = "switchboard-producer-${var.environment}-security-group"
  }
}

resource "aws_security_group_rule" "allow_producer_outbound_to_the_world" {
  type              = "egress"
  from_port         = 0
  to_port           = 0
  protocol          = "-1"
  cidr_blocks       = ["0.0.0.0/0"]
  security_group_id = aws_security_group.lambda_producer_security_group.id
}

resource "aws_security_group_rule" "allow_producer_inbound_from_orcd_subnets" {
  type              = "ingress"
  from_port         = 0
  to_port           = 0
  protocol          = "-1"
  cidr_blocks       = var.allow_cidr_blocks
  security_group_id = aws_security_group.lambda_producer_security_group.id
}

resource "aws_security_group_rule" "allow_producer_inbound_from_task_subnet" {
  type                     = "ingress"
  from_port                = 0
  to_port                  = 0
  protocol                 = "-1"
  source_security_group_id = module.daemon_switchboard_consumer_environment.fargate_security_group_id

  security_group_id = aws_security_group.lambda_producer_security_group.id
}


module "lambda_switchboard_producer" {
  source = "git@github.com:theorchard/terraform-lambda.git//?ref=1.0.2"

  environment                                    = var.environment
  use_custom_function_name                       = true
  custom_function_name                           = "switchboard-producer-${var.environment}"
  lambda_name                                    = "switchboard-producer"
  lambda_runtime                                 = "python3.6"
  lambda_description                             = "Notifies Kafka about metadata changes"
  lambda_function_package_path                   = "lambda.zip"
  lambda_function_timeout                        = "300"
  lambda_function_handler                        = "index.handler"
  lambda_function_reserved_concurrent_executions = -1
  vpc_subnet_ids                                 = ["subnet-0039792f783ab75fd", "subnet-0dd9a0984ce97daf3"]
  vpc_security_group_ids                         = [aws_security_group.lambda_producer_security_group.id]
  event_source_mapping_enabled                   = true
  event_source_mapping_resource_type             = "kinesis"
  event_source_mapping_stream_name               = module.switchboard_kinesis_stream.kinesis_stream_name
  event_source_mapping_batch_size                = "10"
  event_source_mapping_starting_position         = "LATEST"
  lambda_function_memory_size                    = "512"
  datadog_enabled                                = false

  iam_managed_policy_attachments = [
    aws_iam_policy.consumer_assume_role_policy.arn,
    aws_iam_policy.kinesis_readonly_policy.arn,
    "arn:aws:iam::437795906767:policy/Dynamo-qa-switchboard-producer-owsrequest",
    aws_iam_policy.consumer_secrets_manager_policy.arn,
  ]

  lambda_function_environment_variables = {
    Environment          = var.environment
    LOGGER_DSN           = "https://${var.environment}-fluentd-applications.theorchard.io:8888/application"
    SENTRY_DSN           = data.aws_secretsmanager_secret_version.producer_sentry_dsn.secret_string
    KAFKA_CLUSTER_ARN    = var.switchboard_kafka_arn
    SWITCHBOARD_ROLE_ARN = "arn:aws:iam::662302927201:role/qa-orchard-access"
    GRAPHQL_URL          = "https://qa-graphql-switchboard.theorchard.io/graphql"
    GRAPHQL_SECRET_NAME  = data.aws_secretsmanager_secret.graphql_consumer_secret.arn
  }
}